ABAPblog.com - FALV (Fast ALV Grid)

ZDEMO_FALV02 - Full screen with redefinitions

Tags: FALV

The latest version of each part of FALV can be found on github repository https://github.com/fidley/falv which you can use in abapGit for easier up to date handling.

Second demo program shows how to use FALV when you want to use event handlers by your own.

"All" events are handled so you just need to redefine proper method starting from evt_*

"! This is demo for FALV with redefinition of hotspot event handler
"! done by Lukasz Pegiel for http://abapblog.com
report zdemo_falv02.

data: sflight type standard table of sflight.

class lcl_test definition inheriting from zcl_falv.
  public section.

  protected section.
    "redefinition of event handler
    methods evt_hotspot_click redefinition.
  private section.

endclass.

class lcl_test implementation.

  method evt_hotspot_click.
    case e_column_id-fieldname.
      when 'SEATSMAX'.
        call function 'POPUP_DISPLAY_MESSAGE'
          exporting
            titel = 'Hotspot is working'   " Title
            msgid = '00'
            msgty = 'I'
            msgno = '001'
            msgv1 = 'Yupi!'.
    endcase.
  endmethod.

endclass.

start-of-selection.

  select * up to 100 rows
  into corresponding fields of table @sflight
  from sflight.

  "creation of falv with local redefinition
  data falv type ref to lcl_test.
  falv ?= lcl_test=>create( exporting  i_subclass = cl_abap_classdescr=>describe_by_name( p_name = 'LCL_TEST' )
                              changing ct_table = sflight    ) .

  "Add hotspot to column 'SEATSMAX'
  falv->column( 'SEATSMAX' )->set_hotspot( abap_true ).
  "Add title variable
  falv->title_v1 = 'ZDEMO_FALV02'.
  "Display full screen grid
  falv->display( ).

9 Comments

ZDEMO_FALV01 - Standard full screen FALV

Tags: FALV

The latest version of each part of FALV can be found on github repository https://github.com/fidley/falv which you can use in abapGit for easier up to date handling.

First demo shows how fast and simple is to use FALV. A table is passed to factory method , title is updated and then full screen grid displayed

"! This is demo for FALV standard fast call
"! done by Lukasz Pegiel for http://abapblog.com
report zdemo_falv01.

data: sflight type standard table of sflight.

start-of-selection.

  select * up to 100 rows
  into corresponding fields of table @sflight
  from sflight.

  "FALV creation with only table passed
  data(falv) = zcl_falv=>create( changing ct_table = sflight ).

  "Add title variable
  falv->title_v1 = 'ZDEMO_FALV01'.
  "Display full screen grid
  falv->display( ).

The result of this program looks like REUSE_ALV_GRID_DISPLAY

0 Comments

FALV (Fast ALV Grid)

Tags: FALV

Finally I've finished to work under FALV. You can find FALV classes in attachment and description under the links. But firstly let's go through few following points:

Why I've created FALV although SALV classes are provided by SAP?

I know SALV classes although I haven't used them often. The main reason was that they don't provide edit mode. So at the end I've always worked with cl_gui_alv_grid class so then whenever users decided that they need one of the field to be editable then I can do it in few seconds/minutes.
But there is a way to make SALV editable!

Yes, I know the solutions of Naimesh Patel (found here) and Paul Hardy (in his ABAP to the Future book) and some other folks to make SALV editable. But In my own opinion, especially when you're at least on 7.40 with SP5 making SALV editable is not needed as you can fast create ALV Grid which does everything you want. To be clear the big advantage of SALV, to call grid output of table in two, three lines when you goes to the code you'll see it's nothing more than call of REUSE_ALV_GRID_DISPLAY... really old FM, which at the end use CL_GUI_ALV_GRID.
Direct reasons

As I used CL_GUI_ALV_GRID so often then I came up with an idea to do some class which will make the creation faster, but I never had time to do it at work. You may know it, because of the time pressure you choose to create report/program/solution in the way you're doing from years ... and then comes another task....and another....

So I've decided to do it at home.... yeah I'm crazy. But at least some of you can also use it.
Advantages
- Fast CL_GUI_ALV_GRID creation
- Replacement of REUSE_ALV_GRID_DISPLAY and REUSE_ALV_GRID_DISPLAY_LVC for a simple editable reports to omit screen creation
- All events are already handled and with redefinition of method I can faster use it
- Faster setting of layout and field catalog attributes
- Easy switch and copy between popup, full screen and container version
- Easy toolbar handling (in grid and in full screen/popup using Dynamic GUI STATUS & TITLE with ABAP code )
- One place to handle user commands of full screen/popup call -> event user_command
Prerequisites

I've worked on this on 7.40 SP8 but this should work also on SP5 as well. Sorry for the users bellow that versions but I'm so used to use new syntax that I couldn't force myself to use old way of coding.

UPDATE: Thanks to Santi Moreno we have now 7.31 version, you can find it here as an attachment ZFALV_V1.1.0.zip. Also GitHub repository is now available here https://github.com/fidley/falv so if you'd like to join us, you're more than welcomed.
Outcome

The outcome of this work is following:

Package ZFALV

I really encourage you to try it and give me your feedback about FALV.

Cheers

Łukasz

130 Comments

FALV (Fast ALV Grid) - First blood

Tags: CL_GUI_ALV_GRID , FALV , REUSE_ALV_GRID_DISPLAY , REUSE_ALV_GRID_DISPLAY_LVC

On one of my last tweets I have mentioned, that I'm working currently on some fast ALV Grid creation class. I know that we have SALV classes which does many of this what I'm trying to achieve here but, many doesn't mean everything. Especially that I really like CL_GUI_ALV_GRID class and this that without any tricks I can make it editable in easy way.

My class in not yet finished but it has already some basic functions available, that's why I'm presenting you just short demo and some screen-shots of the code. I will of course put a nugget here as fast as I'll finish more than alpha release.

Basically what I try to get from this class:

Fast CL_GUI_ALV_GRID creation
Replacement of REUSE_ALV_GRID_DISPLAY and REUSE_ALV_GRID_DISPLAY_LVC for a simple editable reports to omit screen creation
All events should be already handled and with redefinition of method I can faster use it
Faster setting of layout and field catalog attributes
Easy switch and copy between popup, full screen and container version
Easy toolbar handling (in grid and in full screen/popup using Dynamic GUI STATUS & TITLE with ABAP code )
One place to handle user commands of full screen/popup call -> event user_command

At the end of the work I'll be able to say: "I've made really good, unnecessary work! " :-)

0 Comments

Eclipse Plugins for ABAP